[ Новые сообщения · Участники · Правила форума · Поиск · RSS ]
Страница 1 из 11
Форум » Наш сайт » Visual basic » Расширения vb (Расширения vb)
Расширения vb
ilimДата: Пятница, 04.02.2011, 05:19 | Сообщение # 1
Генералиссимус
Группа: Администраторы
Сообщений: 680
Награды: 17
Репутация: 4
Статус: Offline
Для регистрации новых расширений нужно воспользоваться реестром. Сейчас мы сделаем программу, которая зарегистрирует новое расширение, и даст ему иконку. На форму кинь кнопку, и создай модуль. Код модуля(взят из шага 74, работа с реестром. Модуль нужен для работы с реестром.):
Код Модуля:
'--------------------------------------------------------------------------------------------------

Public Const REG_SZ As Long = 1
Public Const REG_DWORD As Long = 4
Public Const HKEY_LOCAL_MACHINE = &H80000002
Public Const HKEY_CLASSES_ROOT = &H80000000
Public Const HKEY_CURRENT_USER = &H80000001
Public Const HKEY_USERS = &H80000003

Public Const ERROR_NONE = 0
Public Const ERROR_BADDB = 1
Public Const ERROR_BADKEY = 2
Public Const ERROR_CANTOPEN = 3
Public Const ERROR_CANTREAD = 4
Public Const ERROR_CANTWRITE = 5
Public Const ERROR_OUTOFMEMORY = 6
Public Const ERROR_INVALID_PARAMETER = 7
Public Const ERROR_ACCESS_DENIED = 8
Public Const ERROR_INVALID_PARAMETERS = 87
Public Const ERROR_NO_MORE_ITEMS = 259
Public Const KEY_ALL_ACCESS = &H3F
Public Const REG_OPTION_NON_VOLATILE = 0

Declare Function RegCloseKey Lib "advapi32.dll" (ByVal hKey As Long) As Long
Declare Function RegCreateKeyEx Lib "advapi32.dll" Alias "RegCreateKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal Reserved As Long, ByVal lpClass As String, ByVal dwOptions As Long, ByVal samDesired As Long, ByVal lpSecurityAttributes As Long, phkResult As Long, lpdwDisposition As Long) As Long
Declare Function RegOpenKeyEx Lib "advapi32.dll" Alias "RegOpenKeyExA" (ByVal hKey As Long, ByVal lpSubKey As String, ByVal ulOptions As Long, ByVal samDesired As Long, phkResult As Long) As Long
Declare Function RegQueryValueExString Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, ByVal lpData As String, lpcbData As Long) As Long
Declare Function RegQueryValueExLong Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, lpData As Long, lpcbData As Long) As Long
Declare Function RegQueryValueExNULL Lib "advapi32.dll" Alias "RegQueryValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal lpReserved As Long, lpType As Long, ByVal lpData As Long, lpcbData As Long) As Long
Declare Function RegSetValueExString Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, ByVal lpValue As String, ByVal cbData As Long) As Long
Declare Function RegSetValueExLong Lib "advapi32.dll" Alias "RegSetValueExA" (ByVal hKey As Long, ByVal lpValueName As String, ByVal Reserved As Long, ByVal dwType As Long, lpValue As Long, ByVal cbData As Long) As Long
Declare Function RegDeleteKey& Lib "advapi32.dll" Alias "RegDeleteKeyA" (ByVal hKey As Long, ByVal lpSubKey As String)
Declare Function RegDeleteValue& Lib "advapi32.dll" Alias "RegDeleteValueA" (ByVal hKey As Long, ByVal lpValueName As String) 'Создание нового ключа
Public Function CreateNewKey(lPredefinedKey As Long, sNewKeyName As String)
Dim hNewKey As Long
Dim lRetVal As Long
lRetVal = RegCreateKeyEx(lPredefinedKey, sNewKeyName, 0&, vbNullString, REG_OPTION_NON_VOLATILE, KEY_ALL_ACCESS, 0&, hNewKey, lRetVal)
RegCloseKey (hNewKey)
End Function

'Запись данных в ключ
Public Function SetKeyValue(lPredefinedKey As Long, sKeyName As String, sValueName As String, vValueSetting As Variant, lValueType As Long)
Dim lRetVal As Long
Dim hKey As Long

lRetVal = RegOpenKeyEx(lPredefinedKey, sKeyName, 0, KEY_ALL_ACCESS, hKey)
lRetVal = SetValueEx(hKey, sValueName, lValueType, vValueSetting)

RegCloseKey (hKey)
End Function

Public Function SetValueEx(ByVal hKey As Long, sValueName As String, lType As Long, vValue As Variant) As Long

Dim lValue As Long
Dim sValue As String

Select Case lType
Case REG_SZ
sValue = vValue
SetValueEx = RegSetValueExString(hKey, sValueName, 0&, lType, sValue, Len(sValue))
Case REG_DWORD
lValue = vValue
SetValueEx = RegSetValueExLong(hKey, sValueName, 0&, lType, lValue, 4)
End Select

End Function

'Возвращает значения записанные в ключе(т.е. чтение)
Public Function QueryValue(lPredefinedKey As Long, sKeyName As String, sValueName As String)

Dim lRetVal As Long
Dim hKey As Long
Dim vValue As Variant
lRetVal = RegOpenKeyEx(lPredefinedKey, sKeyName, 0, KEY_ALL_ACCESS, hKey)
lRetVal = QueryValueEx(hKey, sValueName, vValue)
QueryValue = vValue
RegCloseKey (hKey)

End Function

Function QueryValueEx(ByVal lhKey As Long, ByVal szValueName As String, vValue As Variant) As Long

Dim cch As Long
Dim lrc As Long
Dim lType As Long
Dim lValue As Long
Dim sValue As String

On Error GoTo QueryValueExError

'Определение размера и типа считываемых данных
lrc = RegQueryValueExNULL(lhKey, szValueName, 0&, lType, 0&, cch)
If lrc <> ERROR_NONE Then MsgBox "Данных (ключа) не существует!", vbExclamation, Form1.Caption
Select Case lType
'Для символьных
Case REG_SZ:
sValue = String(cch, 0)
lrc = RegQueryValueExString(lhKey, szValueName, 0&, lType, sValue, cch)
If lrc = ERROR_NONE Then
vValue = Left$(sValue, cch)
Else
vValue = Empty
End If
'Для числовых
Case REG_DWORD:
lrc = RegQueryValueExLong(lhKey, szValueName, 0&, lType, lValue, cch)
If lrc = ERROR_NONE Then vValue = lValue
'Для остальных не поддержанных типов данных
Case Else
lrc = -1
End Select
QueryValueExExit:
QueryValueEx = lrc
Exit Function
QueryValueExError:
Resume QueryValueExExit
End Function

'Удаление значений ключа
Public Function DeleteValue(lPredefinedKey As Long, sKeyName As String, sValueName As String)
Dim lRetVal As Long
Dim hKey As Long
lRetVal = RegOpenKeyEx(lPredefinedKey, sKeyName, 0, KEY_ALL_ACCESS, hKey)
lRetVal = RegDeleteValue(hKey, sValueName)
RegCloseKey (hKey)
End Function

'Удаление ключа
Public Function DeleteKey(lPredefinedKey As Long, sKeyName As String)
Dim lRetVal As Long
lRetVal = RegDeleteKey(lPredefinedKey, sKeyName)
End Function

'-------------------------------------------------------------------------------------------------------

Теперь код формы. Скажу последовательность действий:
1. Надо создать ключ в реестре с разделе HKEY_CLASSES_ROOT с нужным расширением(например ".cdk").
2. Значение стокового параметра "(По умолчанию)" в созданном ключе, надо изменить на имя своей программы(например "cdkfile"(вместо ""))
3. Надо создать еще один ключ, с тем именем, который ты внес в значение строкого параметра "По умолчанию" предыдущем ключе(пред. ключ ".cdk", значение "cdkfile"). В этом ключе мы и будем создавать ключи, отвечающие за какие - либо действия(например открытие файла, или присвоение иконки, или печать..)
4. Значение срокового параметра "По умолчанию" ключа("cdkfile") можно изменить на любой текст. И этот текст будет отображаться в свойствах файла, в разделе "Общие>Тип Файла", если стоит XP, то под файлом.
5. Для прикрепления иконки к созданному расширению, нодо создать в ключе "cdkfile" подключ "DefaultIcon", и значение строкового параметра "По умолчанию" надо изменить на путь к иконке(причем путь может быть не только в *.ico файлам, но и к *.exe файлам. И тогда иконка возьмется из exe файла.).
6. О всех действиях ты узнаешь(если захочешь) сам(посмотрев ключи других программ, например, ключи .ini файла, или .txt, или др. файлов), я скажу тебе о действии "Открыть". В ключе "cdkfile" создаешь подключи:
HKEY_CLASSES_ROOT
- cdkfile
- shell
- open
- command

Значение строкового параметра "По умолчанию" ключа command, должен быть путь к программе, которая будет открываться при двойном клике на файле с расширение .cdk(ну который мы почти создали).
Вот как это будет выглядеть программно(т.е. код формы):

Private Sub Command1_Click()
' Создаем файл с расширением *.CDK, ну это чтобы убедится что новый тип создан.
Open "New_Tip.cdk" For Output As #1
Print #1, "Новый тип"
Close #1

' Создаем основные ключи
CreateNewKey HKEY_CLASSES_ROOT, ".cdk"' Для чего этот ключ нужен, смотри выше(№ 1)
CreateNewKey HKEY_CLASSES_ROOT, "cdkfile\DefaultIcon"' Этот ключ для иконки
CreateNewKey HKEY_CLASSES_ROOT, "cdkfile\shell\open\command"' Этот ключ для действия откорыть

' Записываем значения строковых параметров:
SetKeyValue HKEY_CLASSES_ROOT, "cdkfile", "", "Новый тип *.CDK", REG_SZ ' Смотри № 4:
SetKeyValue HKEY_CLASSES_ROOT, "cdkfile\DefaultIcon", "", App.Path & "\" & "1.exe", REG_SZ ' Записываем путь к иконке, иконка берется из файла 1.exe, который находится в той же папке где и сама программа
SetKeyValue HKEY_CLASSES_ROOT, ".cdk", "", "cdkfile", REG_SZ ' Записываем путь к ключу, смотри № 2
SetKeyValue HKEY_CLASSES_ROOT, "cdkfile\shell\open\command", "", App.Path & "\" & "1.exe", REG_SZ ' Вместо App.Path & "\" & "1.exe" укажи путь к своей программе(№ 6)
End Sub

Теперь перезагрузи комп(без этого иконка не появтся, т.к. она только после перезагрузки появляется), и любуйся


www.ilim.kz
 
Форум » Наш сайт » Visual basic » Расширения vb (Расширения vb)
Страница 1 из 11
Поиск: